home *** CD-ROM | disk | FTP | other *** search
/ MACD 5 (Alt) / MACD 5.bin / workbench / tools / czesc_1 / dr / source / purify.a < prev    next >
Encoding:
Text File  |  1994-02-23  |  9.3 KB  |  248 lines
  1. * This here is startup code for Amiga Aztec C programs, to make them pure.
  2. * Assemble it with the command "as purify.a" and link the resulting purify.o
  3. * file with your C program, in some manner like "ln yourprogram.o purify.o -lc",
  4. * and your program can then be marked as pure, and made resident, IF it meets
  5. * certain conditions:
  6. * 
  7. * 1) You must not use the large data model for accessing your global variables.
  8. * 
  9. * 2) You MUST NOT call the geta4() function from within any part of your program
  10. * that is run outside of your main process.  Subtasks, interrupt handlers, and
  11. * wedges installed with SetFunction may not use geta4, and thus may not access
  12. * your global variables by any direct method.  Note that #pragma intfunc causes
  13. * an implicit call of geta4().
  14. * 
  15. * 3) You must not initialize global variables using the addresses of other
  16. * global variables.  For example, the following is not correct:
  17. * 
  18. *     char foo[100], bar[100];
  19. *     char *foobar[2] = { foo, bar };        /* WRONG */
  20. * 
  21. * If you do this, then any references to foobar[0] will end up accessing
  22. * DIFFERENT MEMORY than accessing foo directly will.  Instead, you have to do
  23. * such initialization in the code, with statements like "foobar[0] = foo;
  24. * foobar[1] = bar;".
  25. *
  26. * 4) You must not use detach.o -- this applies to ALL pure programs, not just
  27. * those that use this startup code.
  28. * 
  29. * 5) Do not use this when making a shared library or device driver.  ("Duh...")
  30. * 
  31. * This was originally based on resident.asm by Olaf Barthel, which is available
  32. * on fish disk 396, but does not contain any of his code.  Barthel's version had
  33. * serious errors in it, and will not work in many cases.  It was also a lot less
  34. * efficient than the method I use.
  35. *
  36. * With the Aztec assembler, do not use the -N flag (one pass), because there's
  37. * a bug that makes the ENTRY directive not work with that option.  It will need
  38. * a few changes in syntax to work with other assemblers.  It might be possible
  39. * to make versions for other C compilers, so I've labeled everything which I
  40. * know to be Aztec specific with a comment containing the word "Aztec".
  41. *
  42. * The one possibly not quite cool bit of programming used here is that I used
  43. * SysBase->ThisTask instead of FindTask(0), in several places.  If they ever
  44. * make an Amiga that runs tasks on several CPUs at once, that might break.
  45. * 
  46. * This is by Paul Kienitz, 1 December 1991, placed in the public domain.
  47. * Revised 11 March 1992 to remove mistake -- DOSBase was accessed after the
  48. * memory it was in was already freed.  A couple other little changes.  Some
  49. * changes to this comment, but not to the code, were made later.
  50.  
  51.  
  52. ; We avoid pulling in include files by copying a few definitions here:
  53.  
  54. MEMB_FAST    equ    2        ; exec/memory.i
  55. MEMB_CLEAR    equ    16        ; exec/memory.i
  56. ThisTask    equ    276        ; exec/execbase.i
  57. AttnFlags    equ    296        ; exec/execbase.i
  58. AFB_68881    equ    4        ; exec/execbase.i
  59. AG_OpenLib    equ    $30000        ; exec/alerts.i
  60. AO_DOSLib    equ    $8007        ; exec/alerts.i
  61. pr_ReturnAddr    equ    176        ; libraries/dosextens.i
  62. pr_CLI        equ    172        ; libraries/dosextens.i
  63. pr_MsgPort    equ    92        ; libraries/dosextens.i
  64.  
  65. _LVOTypeOfMem        equ    -534
  66. _LVOAllocMem        equ    -198
  67. _LVOOldOpenLibrary    equ    -408
  68. _LVOAlert        equ    -108
  69. _LVOSupervisor        equ    -30
  70. _LVOFreeMem        equ    -210
  71. _LVOCloseLibrary    equ    -414
  72. _LVOWaitPort        equ    -384
  73. _LVOGetMsg        equ    -372
  74. _LVOReplyMsg        equ    -378
  75. _LVOForbid        equ    -132
  76.  
  77.  
  78. lcall        macro
  79.         jsr    _LVO\1(a6)
  80.         endm
  81.  
  82. AbsExecBase    equ    (4).w
  83.  
  84.         xdef    .begin,_geta4
  85.         xref    __main,_SysBase,_DOSBase
  86.         xref    __savsp                    ; Aztec
  87. ;;        xdef    entree,cleanup        ; for debugging
  88.  
  89. ; the use of the label ".begin" for the entry point is an Aztec-ism
  90.         entry    .begin
  91.  
  92. .begin:
  93. entree:
  94.         far    data                    ; Aztec
  95.         lea    __H1_org+32766,a4    ; to access original globals
  96.  
  97.         lea    __H1_end,a1        ; Aztec; end of initialized data
  98.         lea    __H2_org,a2        ; Aztec; start of BSS
  99.         near    data                    ; Aztec
  100.  
  101.         cmp.l    a1,a2            ; the same address?
  102.         bne    bomb            ; if not, refuse to run
  103.  
  104.         move.l    a0,d6            ; save command arg-line pointer
  105.         move.l    d0,d5            ; save command arg length
  106.  
  107.         lea    __H1_org,a1        ; Aztec; start of data hunk
  108.         move.l    AbsExecBase,a6
  109.         lcall    TypeOfMem        ; what kind of ram is it in?
  110.         bclr.l    #MEMB_FAST,d0        ; do NOT force fast ram!
  111.         bset.l    #MEMB_CLEAR,d0        ; do force cleared memory
  112.  
  113.         move.l    d0,d1            ; memory type requirements
  114.         move.l    #(__H2_end-__H1_org),d0    ; Aztec; size of all globals
  115.         lcall    AllocMem        ; space for a complete copy
  116.         tst.l    d0
  117.         beq    bomb            ; if it failed, don't run
  118.         move.l    d0,a2
  119.  
  120.         lea    __H1_org,a0        ; Aztec; address of old globals
  121.         move.l    a2,a1            ; address of new globals
  122.         move.l    #((__H1_end-__H1_org)/4)-1,d0    ; Aztec; size to copy
  123. copyit:        move.l    (a0)+,(a1)+        ; copy all initialized data
  124.         dbra    d0,copyit
  125.  
  126. * Here's where we get tricky.  We need to put the address of our dublicated
  127. * global variable space someplace where it can be found by geta4(), and we need
  128. * to make sure that we free the copied globals no matter how the program exits.
  129. * What we do is save the pointer on the stack, and then make it appear that the
  130. * final exit address that the program must return to is the address of our
  131. * cleanup routine.  To do this, after pushing the pointer to the copied globals,
  132. * we push the size of the remaining available stack (12 bytes less than the
  133. * original size) and then the address of the cleanup code.  We set the variable
  134. * __savsp to point to that cleanup code address, so that the Aztec exit()
  135. * function will return to that point.  We set the pr_ReturnAddr field of our
  136. * struct Process to point one longword above that, to make the dos.library
  137. * Exit() function return to the cleanup code.  This is also used by geta4() to
  138. * locate the saved pointer to the copied globals.
  139.  
  140.         move.l    a2,-(sp)        ; where geta4() can find it
  141.         move.l    8(sp),a0        ; original size of the stack
  142.         sub.w    #12,a0            ; minus space we're using
  143.         move.l    a0,-(sp)        ; make stack look smaller
  144.         move.l    ThisTask(a6),a0        ; equivalent to FindTask(0)
  145.         move.l    sp,pr_ReturnAddr(a0)    ; for geta4() and dos Exit()
  146.         pea    cleanup            ; so everybody goes there
  147.  
  148. * The stack now looks like this:
  149. *
  150. *     Stack size in bytes        <-  old pr_ReturnAddr pointed here
  151. *     Return address for final exit    <-  __savsp would have pointed here
  152. *     Pointer to globals for geta4    <-  also used by cleanup
  153. *     New stack size, minus twelve    <-  new pr_ReturnAddr points here
  154. *     Fake return address: cleanup    <-  __savsp will point here
  155. *
  156. * Once __main is called, there will also be these:
  157. *
  158. *     Command line arg address    <-  argument to __main
  159. *     Command line arg length        <-  argument to __main ...SP is now here
  160. *     Return address to this module    <-  falls through to cleanup
  161.  
  162.         bsr    _geta4            ; use new globals
  163.         move.l    sp,__savsp        ; Aztec; exit() and stack check
  164.         move.l    a6,_SysBase        ; set up base for C program
  165.         lea    dosname,a1
  166.         lcall    OldOpenLibrary        ; open dos.library
  167.         move.l    d0,_DOSBase        ; set up another base
  168.         bne    dosokay
  169.         move.l    #AG_OpenLib!AO_DOSLib,d7    ; recoverable - no dos
  170.         lea    ThisTask(a6),a5        ; make it show our task adr
  171.         lcall    Alert            ; frighten the user
  172.         moveq    #127,d0            ; return value
  173.         rts                ; "returns" to cleanup
  174.  
  175. dosokay:    btst.b    #AFB_68881,AttnFlags+1(a6)    ; is there an FPU?
  176.         beq    nofpu
  177.         lea    resetfpu,a5
  178.         lcall    Supervisor        ; reset it in supervisor mode
  179.  
  180. nofpu:        movem.l    d5/d6,-(sp)        ; pass arguments to _main()
  181.         jsr    __main            ; RUN THE PROGRAM!
  182.         add.w    #12,sp            ; simulate rts to cleanup
  183.  
  184. cleanup:    move.l    d0,d7            ; set aside the return value
  185.         bsr    _geta4            ; so we can check DOSBase
  186.         move.l    AbsExecBase,a6
  187.         move.l    _DOSBase,a1
  188.         move.l    a1,d0            ; fake tst.l a1
  189.         beq    dosneveropen        ; was there ever a DOSBase?
  190.         lcall    CloseLibrary        ; if yes, close it
  191.  
  192. dosneveropen:    move.l    4(sp),a1        ; address of copied globals
  193.         move.l    #(__H2_end-__H1_org),d0    ; size of copied globals
  194.         lcall    FreeMem            ; get rid of the copy
  195.         addq    #8,sp            ; restore primordial stack
  196.         move.l    ThisTask(a6),a1
  197.         lea    4(sp),a0        ; just to be paranoid...
  198.         move.l    a0,pr_ReturnAddr(a1)    ; restore old pr_ReturnAddr
  199.  
  200.         move.l    d7,d0            ; restore the return value
  201.         rts                ; goodbye cruel world
  202.  
  203.  
  204. bomb:        move.l    AbsExecBase,a6        ; come here if we can't run
  205.         move.l    ThisTask(a6),a0
  206.         tst.l    pr_CLI(a0)        ; are we a Workbench process?
  207.         bne    noworkbench        ; if yes, then we need to
  208.                         ;   reply the startup message:
  209.         lea    pr_MsgPort(a0),a0
  210.         move.l    a0,a3            ; remember our msgport address
  211.         lcall    WaitPort        ; here come de message
  212.         move.l    a3,a0
  213.         lcall    GetMsg            ; got it
  214.         move.l    d0,a3            ; yes, remember it
  215.         lcall    Forbid            ; standard shutdown procedure
  216.         move.l    a3,a1
  217.         lcall    ReplyMsg        ; tell WB to unload us
  218.  
  219. noworkbench:    moveq    #127,d0            ; largest convenient return code
  220.         rts                ; might return to cleanup
  221.  
  222.  
  223.         mc68881        ; Aztec; activate FPU instruction opcodes
  224.  
  225. resetfpu:    clr.l    -(sp)            ; call this in supervisor mode
  226.         frestore (sp)+            ; reset the FPU
  227.         rte                ; return to user mode
  228.  
  229.  
  230. * Here's our magic routine to set up a4 for accessing the copied globals.
  231. * CALL ONLY FROM WITHIN THE SAME PROCESS.
  232.  
  233. _geta4:        move.l    AbsExecBase,a4
  234.         move.l    ThisTask(a4),a4
  235.         move.l    pr_ReturnAddr(a4),a4    ; ptr to FAKE stack size
  236.         move.l    4(a4),a4        ; stored ptr to copied globals
  237.         lea    32766(a4),a4        ; add the offset
  238.         rts
  239.  
  240. dosname:    dc.b    'dos.library',0        ; for OldOpenLibrary
  241.  
  242.         dseg                ; Aztec
  243. ; Assembler bug:  If you declare __H1_org public within the code segment,
  244. ; then the assembler refers to it with small data even if you have told
  245. ; it to use large data.  Hence the above dseg is necessary.  This does not seem
  246. ; to happen with ordinary symbols, just the __Hx_xxx ones.
  247.         public    __H1_org,__H1_end,__H2_org,__H2_end    ; Aztec
  248.